| 1 | # Generate a list of CMake library targets so that other CMake projects can |
|---|
| 2 | # link against them. LLVM calls its version of this file LLVMExports.cmake, but |
|---|
| 3 | # the usual CMake convention seems to be ${Project}Targets.cmake. |
|---|
| 4 | set(CLANG_INSTALL_PACKAGE_DIR lib${LLVM_LIBDIR_SUFFIX}/cmake/clang) |
|---|
| 5 | set(clang_cmake_builddir "${CMAKE_BINARY_DIR}/${CLANG_INSTALL_PACKAGE_DIR}") |
|---|
| 6 | |
|---|
| 7 | # Keep this in sync with llvm/cmake/CMakeLists.txt! |
|---|
| 8 | set(LLVM_INSTALL_PACKAGE_DIR lib${LLVM_LIBDIR_SUFFIX}/cmake/llvm) |
|---|
| 9 | set(llvm_cmake_builddir "${LLVM_BINARY_DIR}/${LLVM_INSTALL_PACKAGE_DIR}") |
|---|
| 10 | |
|---|
| 11 | get_property(CLANG_EXPORTS GLOBAL PROPERTY CLANG_EXPORTS) |
|---|
| 12 | export(TARGETS ${CLANG_EXPORTS} FILE ${clang_cmake_builddir}/ClangTargets.cmake) |
|---|
| 13 | |
|---|
| 14 | # Generate ClangConfig.cmake for the build tree. |
|---|
| 15 | set(CLANG_CONFIG_CMAKE_DIR "${clang_cmake_builddir}") |
|---|
| 16 | set(CLANG_CONFIG_LLVM_CMAKE_DIR "${llvm_cmake_builddir}") |
|---|
| 17 | set(CLANG_CONFIG_EXPORTS_FILE "${clang_cmake_builddir}/ClangTargets.cmake") |
|---|
| 18 | set(CLANG_CONFIG_INCLUDE_DIRS |
|---|
| 19 | "${CLANG_SOURCE_DIR}/include" |
|---|
| 20 | "${CLANG_BINARY_DIR}/include" |
|---|
| 21 | ) |
|---|
| 22 | configure_file( |
|---|
| 23 | ${CMAKE_CURRENT_SOURCE_DIR}/ClangConfig.cmake.in |
|---|
| 24 | ${clang_cmake_builddir}/ClangConfig.cmake |
|---|
| 25 | @ONLY) |
|---|
| 26 | set(CLANG_CONFIG_CMAKE_DIR) |
|---|
| 27 | set(CLANG_CONFIG_LLVM_CMAKE_DIR) |
|---|
| 28 | set(CLANG_CONFIG_EXPORTS_FILE) |
|---|
| 29 | |
|---|
| 30 | # Generate ClangConfig.cmake for the install tree. |
|---|
| 31 | set(CLANG_CONFIG_CODE " |
|---|
| 32 | # Compute the installation prefix from this LLVMConfig.cmake file location. |
|---|
| 33 | get_filename_component(CLANG_INSTALL_PREFIX \"\${CMAKE_CURRENT_LIST_FILE}\" PATH)") |
|---|
| 34 | # Construct the proper number of get_filename_component(... PATH) |
|---|
| 35 | # calls to compute the installation prefix. |
|---|
| 36 | string(REGEX REPLACE "/" ";" _count "${CLANG_INSTALL_PACKAGE_DIR}") |
|---|
| 37 | foreach(p ${_count}) |
|---|
| 38 | set(CLANG_CONFIG_CODE "${CLANG_CONFIG_CODE} |
|---|
| 39 | get_filename_component(CLANG_INSTALL_PREFIX \"\${CLANG_INSTALL_PREFIX}\" PATH)") |
|---|
| 40 | endforeach(p) |
|---|
| 41 | set(CLANG_CONFIG_CMAKE_DIR "\${CLANG_INSTALL_PREFIX}/${CLANG_INSTALL_PACKAGE_DIR}") |
|---|
| 42 | set(CLANG_CONFIG_LLVM_CMAKE_DIR "\${CLANG_INSTALL_PREFIX}/${LLVM_INSTALL_PACKAGE_DIR}") |
|---|
| 43 | set(CLANG_CONFIG_EXPORTS_FILE "\${CLANG_CMAKE_DIR}/ClangTargets.cmake") |
|---|
| 44 | set(CLANG_CONFIG_INCLUDE_DIRS |
|---|
| 45 | "\${CLANG_INSTALL_PREFIX}/include" |
|---|
| 46 | ) |
|---|
| 47 | configure_file( |
|---|
| 48 | ${CMAKE_CURRENT_SOURCE_DIR}/ClangConfig.cmake.in |
|---|
| 49 | ${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/ClangConfig.cmake |
|---|
| 50 | @ONLY) |
|---|
| 51 | set(CLANG_CONFIG_CODE) |
|---|
| 52 | set(CLANG_CONFIG_CMAKE_DIR) |
|---|
| 53 | set(CLANG_CONFIG_EXPORTS_FILE) |
|---|
| 54 | |
|---|
| 55 | if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY) |
|---|
| 56 | get_property(clang_has_exports GLOBAL PROPERTY CLANG_HAS_EXPORTS) |
|---|
| 57 | if(clang_has_exports) |
|---|
| 58 | install(EXPORT ClangTargets DESTINATION ${CLANG_INSTALL_PACKAGE_DIR} |
|---|
| 59 | COMPONENT clang-cmake-exports) |
|---|
| 60 | endif() |
|---|
| 61 | |
|---|
| 62 | install(FILES |
|---|
| 63 | ${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/ClangConfig.cmake |
|---|
| 64 | DESTINATION ${CLANG_INSTALL_PACKAGE_DIR} |
|---|
| 65 | COMPONENT clang-cmake-exports) |
|---|
| 66 | |
|---|
| 67 | if(NOT LLVM_ENABLE_IDE) |
|---|
| 68 | # Add a dummy target so this can be used with LLVM_DISTRIBUTION_COMPONENTS |
|---|
| 69 | add_custom_target(clang-cmake-exports) |
|---|
| 70 | add_llvm_install_targets(install-clang-cmake-exports |
|---|
| 71 | COMPONENT clang-cmake-exports) |
|---|
| 72 | endif() |
|---|
| 73 | endif() |
|---|
| 74 | |
|---|